*******K ESTIMATION BY ARM******************************************************


***cluster average prev:
bysort Arm_no: egen cluster_mean_prev=mean(Pf_prev)

***Overall average prev:
bysort Arm_no: egen overall_n_pos=sum(n_Pf_pos)
bysort Arm_no: egen overall_n_tested=sum(N_tested)
gen Overall_mean_prev=overall_n_pos/overall_n_tested
drop overall_n_pos overall_n_tested

**Harmonic mean of cluster size:
bysort Arm_no: egen count_tested=count(N_tested)
bysort Arm_no: gen one_over_n=1/N_tested
bysort Arm_no: egen sum_one_over_n=sum(one_over_n)
bysort Arm_no: gen harmean_cluster_N= count_tested/sum_one_over_n
drop count_tested one_over_n sum_one_over_n

**Sum square differences:
gen prev_mean_difference=Pf_prev-cluster_mean_prev
gen difference2=prev_mean_difference*prev_mean_difference
bysort Arm_no: egen sum_of_squares=sum(difference2)
drop difference2 prev_mean_difference

****Cluster n-1:
bysort Arm_no: egen c_no=count(Cluster_no)
gen c_no_minus_1=c_no-1
drop c_no

***Estimate k:
gen s2=sum_of_squares/c_no_minus_1
gen variance=s2-((Overall_mean_prev*(1-Overall_mean_prev))/harmean_cluster_N)
gen SD=sqrt(variance)
gen k_per_trial_survey=SD/Overall_mean_prev
drop SD variance s2 c_no_minus_1 sum_of_squares harmean_cluster_N Overall_mean_prev cluster_mean_prev