


Supplementary material
S1: TRIPOD Checklist
Title and Abstract
Item 1: Title
The title identifies the study as an external validation study of prediction models.
Item 2: Abstract
The abstract provides information on the study objective, study design, participants, predictors, outcomes, statistical analysis, model performance, and conclusions.
Introduction
Item 3: Background and objectives
The study background describes the clinical importance of postoperative stress urinary incontinence after pelvic organ prolapse surgery and the need for externally validating existing prediction models.
Item 4: Objectives
The objective of this study was to externally validate and compare currently available prediction models for postoperative stress urinary incontinence in Chinese women undergoing pelvic organ prolapse surgery.
Methods
Item 5: Source of data
A multicenter retrospective cohort was established using medical records from three Chinese medical centers.
Item 6: Participants
Participants were women with POP-Q stage 2–4 apical or anterior prolapse who underwent prolapse surgery and completed 1-year follow-up.
[bookmark: _GoBack]Item 7: Outcome
The primary outcome was bothersome postoperative stress urinary incontinence and/or treatment for postoperative stress urinary incontinence within 1 year after prolapse surgery.
Item 8: Predictors
Candidate predictors were selected according to previously developed prediction models, including demographic characteristics, clinical factors, POP-Q measurements, surgical procedures, and concomitant midurethral sling insertion.
Item 9: Sample size
The sample size was calculated according to recommendations for external validation of clinical prediction models with binary outcomes.
Item 10: Missing data
Missing data were handled using multiple imputation methods, and sensitivity analyses were performed.
Item 11: Statistical analysis
Model performance was evaluated using overall performance, calibration, and discrimination measures, including Brier score, observed/expected ratio, calibration slope, integrated calibration index, and AUROC.
Results
Item 12: Participants
The study included 673 women from three Chinese medical centers.
Item 13: Model performance
The predictive performance of the Netherlands model and Korea model was evaluated and compared.
Item 14: Calibration and discrimination
Calibration was assessed using calibration curves, observed/expected ratio, calibration slope, and integrated calibration index. Discrimination was evaluated using AUROC.
Discussion
Item 15: Interpretation
The study discusses the applicability and limitations of existing prediction models in Chinese women undergoing pelvic organ prolapse surgery.
Item 16: Limitations
The study limitations, including retrospective design, unavailable prolapse reduction stress testing, and need for further validation in other populations, are discussed.
Item 17: Clinical implications
The findings suggest that externally validated prediction models may assist individualized counseling and shared decision-making regarding concomitant anti-incontinence procedures.
Conclusion
This study provides an external validation assessment of existing postoperative stress urinary incontinence prediction models and highlights the importance of evaluating model transportability before clinical implementation.

S2: Stata code to calculate required sample size
* SAMPLE SIZE CALCULATIONS
* STEP (i): O/E calculation
* target confidence interval width of 0.5 for O/E; assuming O/E is 1 then this
* corresponds to SE(lnOE) of 0.128
clear all
* inputs
global selnoe = 0.128
global outcome_prop = 0.20
* calculation
global sampsize_OE = (1-$outcome_prop)/($outcome_prop*$selnoe*$selnoe)
disp "Required sample size (events) for O/E = " $sampsize_OE " (" $sampsize_OE*$outcome_prop ")" 

* STEP (ii): calibration slope calculation
*Obtaining the linear predictor distribution from the C-statistic under the assumption of normality and equal variances of the linear prediction distribution in each group
* SET-UP for the sample size calculation
clear all 
* Well assume a normal distribution in both outcome groups with the same variance (s2)
* and we can use the C-statistic of 0.75 reported for the previous prediction model
disp 2*(invnorm(0.75)^2)
* s2 = .90987285
* now we need to find the means of the distributions so that we match the outcome event proportion of 0.20
* this just involved trial and error to find the means in the non-events group,
* as the mean in the outcome event group is a function of that mean and s2 .
* Solution for the mean is when the overall outcome event proportion is 0.20 in a simulated dataset
* looks like a mean of -1.8 is close
clear all
set obs 10000
set seed 1234
gen outcome = rbinomial(1,0.20)
* non-events group
gen LP = rnormal(-1.8, sqrt( .90987285))
* events group mean is non-events group mean + S2 
replace LP = rnormal(-1.8 +  .90987285, sqrt( .90987285)) if outcome == 1
hist LP
* looks similar to Pavlou, though perhaps not quite as wide or asymmetrical
gen P = exp(LP)/(1+exp(LP)) 
gen outcome_test = rbinomial(1,P)
summ outcome_test
* gives 0.20, very close to outcome event proportion of 0.20
* check C-statistic is correct
roctab outcome LP 
* gives C-statistic of 0.75 as required.

*Implementing this in the sample size calculation for the calibration slope
clear all
set obs 1000000
set seed 1234
gen outcome = rbinomial(1,0.20)
* non-events group
gen LP = rnormal(-1.8, sqrt(.90987285))
* events group mean is non-events group mean + S2 
replace LP = rnormal(-1.8 + .909872856, sqrt(.90987285)) if outcome == 1
* input assumed parameters of calibration model
global beta0 = 0
global beta1 = 1
* calculate elements of I matrix
gen Borenstein_00 = exp($beta0 + ($beta1*LP))/((1+ exp($beta0 + ($beta1 *LP)))^2)
gen Borenstein_01 = LP*exp($beta0 + ($beta1 *LP))/((1+ exp($beta0 + ($beta1 *LP)))^2)
gen Borenstein_11 = LP*LP*exp($beta0 + ($beta1 *LP))/((1+ exp($beta0 + ($beta1 *LP)))^2)
qui summ Borenstein_00
global I_00 = r(mean)
disp "I_00 =" r(mean)
qui summ Borenstein_01
global I_01 = r(mean)
disp "I_01 =" r(mean)
qui summ Borenstein_11
global I_11 = r(mean)
disp "I_11 =" r(mean)
* input desired SE: target a CI width of 0.5, which corresponds to a SE of 0.128
global seslope = 0.128
* alternatively: local seslope = CIwidth/(2*1.96)
* input outcome event proportion
global outcome_prop = 0.20
* calculate sample size
global sampsize_slope = ($I_00 / ($seslope * $seslope * (($I_00 * $I_11) - ($I_01 * $I_01))))

disp "Required sample size (events) for calibration slope = " $sampsize_slope " (" $sampsize_slope*$outcome_prop ")"

* STEP (iii): C-statistic calculation
* target a CI width of 0.1, which equates to a SE of 0.02551 
clear all
* inputs
global outcome_prop = 0.20
global Cstat = 0.75
* No closed form solution so need an iterative or deductive approach
* First calculate the SE for a range of N
set obs 10000000
gen size = _n
gen seCstatsq = $Cstat*(1-$Cstat)*(1+(((size/2)-1)*((1-$Cstat)/(2-$Cstat)))+((((size/2)-1)*$Cstat)/(1+$Cstat)))/(size*size*$outcome_prop*(1-$outcome_prop))
gen seCstat = sqrt(seCstatsq)
gen CIwidth = 2*1.96*seCstat 
* Now identify the sample sizes that give a CIwidth no wider than the desired value
drop if CIwidth>0.1000
* Finally identify the minimum of all these sample sizes
qui summ size
global sampsize_Cstat = r(min)
disp "Required sample size (events) for C-statistic " $sampsize_Cstat " (" $sampsize_Cstat*$outcome_prop ")"

* STEP (iv): Net benefit calculation
* target an anticipated outcome event proportion of 0.20, a sensitivity of 0.75 and a specificity of 0.54 at risk threshold of 0.30；
* target an anticipated outcome event proportion of 0.20, a sensitivity of 0.68 and a specificity of 0.62 at optimal risk threshold of 0.17；
clear all
* inputs 
global outcome_prop = 0.20
global sens = 0.75
global spec = 0.54
global threshold = 0.30
global NB = ($sens*$outcome_prop) - ((1-$spec)*(1-$outcome_prop)*($threshold/(1-$threshold)))
global sNB = $NB/$outcome_prop
* calculate NB and sNB
disp "net benefit =  $NB 
disp "standardised net benefit = " $sNB
global w = ((1-$outcome_prop)/$outcome_prop)*($threshold/(1-$threshold))
* target CI width for sNB of 0.5, which corresponds to SE of 0.128
* input SE
global sesNB = 0.128
* calculate sample size
global sampsize_sNB = (1/($sesNB^2))*((($sens*(1-$sens))/$outcome_prop)+($w*$w*$spec*(1-$spec)/(1-$outcome_prop))+($w*$w*(1-$spec)*(1-$spec)/($outcome_prop*(1-$outcome_prop))))
disp "Required sample size (events) for standardised net benefit = " $sampsize_sNB " (" $sampsize_sNB*$outcome_prop ")"

* STEP (v): Summary of findings
disp "Required sample size (events) for O/E = " $sampsize_OE " (" $sampsize_OE*$outcome_prop ")" _newline "Required sample size (events) for calibration slope = " $sampsize_slope " (" $sampsize_slope*$outcome_prop ")" _newline "Required sample size (events) for C-statistic " $sampsize_Cstat " (" $sampsize_Cstat*$outcome_prop ")"  _newline "Required sample size (events) for standardised net benefit = " $sampsize_sNB " (" $sampsize_sNB*$outcome_prop ")"
Required sample size (events) for O/E = 244.14063 (48.828125)
Required sample size (events) for calibration slope = 554.36239 (110.87248)
Required sample size (events) for C-statistic 568 (113.6)
Required sample size (events) for standardised net benefit = 350.12942 (70.025884)

S3: Summary of previous models 
Nmodel: 
The formula for risk: Risk = 1/[1 + exp(score)]. 
Score reference model: –4.44 + [0.57 × (age < 55 years + Ba < 4 + 3 × subjective UI + 2 × MUS)].
Kmodel:
Logistic regression equation of the model without the stress test: 3.42 + 1.01 × age (≥ 55 years) + 0.59 × diabetes mellitus + 0.97 × subjective urinary incontinence – 2.44 × concomitant midurethral sling + 0.68 × sacrocolpopexy.

