
Supplementary Materials and Methods

Bayesian modeling of AGC recovery
All data and statistical analyses were carried out using RStudio1 and the Stan programming language2, through the rstan package (version 2.32.7)3. For a given data model and prior distributions, Stan simulates draws from the posterior distribution through the No-U-Turn-Sampler (NUTS), a specific Markov-Chain Monte Carlo (MCMC) algorithm. The use of MCMC enables efficient exploration of the posterior probability space by generating samples that are more likely to fall in regions of high posterior density, thereby improving convergence and reducing computational cost2. For all modeled and calculated parameters, 90% credible intervals (CI) were calculated as the lower and upper 5% quantiles of the corresponding draws from the posterior probability distribution. 
Recovery model 
The recovery of AGC to the OGF reference state was modeled using the following sigmoidal function, inspired by the Chapman-Richards growth model4,5(equation 1).
 			(1)
with µX,t [Mg C ha-1] the AGC recovery at time t for a specific site X, αX [Mg C ha-1] the site-specific modeled starting value of succession (i.e. the value for µX,t(t = 0), which accounts for the standing biomass due to remnant trees), ωX [Mg C ha-1] the site-specific modeled asymptotic value (i.e. the OGF situation), λX [year-1] the site-specific intrinsic recovery rate, and δX the instantaneous growth rate in the inflection point of the sigmoidal curve [dimensionless].
In each iteration, the likelihood of observed data points from both SF and OGF plots - given the parameter values proposed by the Stan algorithm - was evaluated against lognormal distributions as follows: 


with AGCt the vector of observed AGC values from secondary forest for a given forest age (here indicated as time t), µX,t the modeled AGC for a site X at time t, σ²X,SF the modeled dispersion of the lognormal law on the observations from secondary forest plots, AGCOGF the vector of observed AGC value from OGF across sites, µX,OGF the modeled AGC for OGF across sites, and σ²X,OGF the modeled dispersion of the lognormal law on the observations from secondary forest plots. Since µX,t also contains a modeled outcome for ωX, OGF reference values could also be estimated in the absence of field-observed OGF data. 
Introduced error on age estimates
Because age estimates of secondary forest plots derived from interviews with local informants are subject to substantial uncertainty due to inaccurate recall or misinterpretation, observed plot ages were treated as uncertain observations of an underlying true stand age. The true age was modeled as a latent variable drawn from a normal distribution with mean equal to the observed age. The standard deviation of this distribution was parameterized such that 90% of the probability mass is located within ±20% of the observed age. 
Hyperlaws and priors
The model contains two hierarchical levels: site-level parameter estimates (the base level) are evaluated on higher-level lognormal hyperdistributions.
The site-specific αX, λX, and δX from equation (1) were additionally modeled in a non-centered parametrization (general form):

with paramX the modeled site-specific or class-level parameter value, medparam,hyper the median of the lognormal hyperlaw on the parameter, paramX,tilde a standard-normally distributed parameter corresponding to paramX, and σ²param,hyper the dispersion of the lognormal hyperlaw on the modeled parameter. All paramX,tilde were thus evaluated on standard-normal priors.
All dispersion parameters (σ) were evaluated on half-normal distributions with µ = 0 and σ = 3. General hyperlaw medians (medparam,general) were evaluated on weakly informative exponential priors in the following way:    




We used exponential priors along with lower bounds of 10-6 (i.e., a very small positive number) specified in Stan’s parameter declarations to ensure strictly positive estimates for the parameters of interest. Lower bounds were set slightly above zero rather than at zero to improve computational efficiency, as Stan evaluates likelihoods on the log scale and struggles with values near zero. Upper bounds for hyperdistributions medians were set to 500 for medα,general, 1 for medλ,general, and 10 for medδ,general, based on expert knowledge and preliminary model runs. These constraints help prevent extremely high parameter values, which are therefore rejected when proposed by the Stan algorithm. Importantly, the bounds are still unrealistically wide to allow the posterior distributions to express their full shape without artificial truncation.
Reinforcing the OGF representation
Because observed OGF values play a key role in shaping the estimated recovery trajectories and asymptotic biomass—yet are typically based on relatively few reference plots compared to the number of secondary forest plots—we specified informative priors for the parameter ωₓ, representing the asymptotic value of the succession trajectory. These priors were derived from the upper 10th percentile of the European Space Agency’s Climate Change Initiative (CCI) biomass map, after masking out regrowing forest areas, thereby capturing a broader, spatially continuous estimate of potential old-growth biomass conditions.
Importantly, OGF measurements entered a likelihood term for the parameter ωₓ, which was separate from secondary forest plots. This approach allows the asymptotic value to be informed both by empirical OGF plot data and by a regionally representative prior, thereby reducing sensitivity to the limited number and potential sampling bias of OGF plots without excluding them from model calibration. 
Biomass was converted to AGC using a conversion factor of 0.456, assuming a wood carbon content of 45.6% for tropical angiosperms6. The mean of the normal prior on log(ωₓ) was defined as the mean of the log-transformed AGC values, and the standard deviation was chosen such that, in the corresponding lognormal distribution of ωₓ, 90% of the probability mass lay within ±100% of the mean, allowing substantial flexibility while remaining informative.
Posterior calculations
The following posterior calculations were executed for each iteration in the Stan algorithm, yielding probability distributions for all calculated variables. 
The time to recovery of X% of the OGF reference AGC stock was derived by dividing both sides of equation (1) by ωX, resulting in a recovery fraction at time t: fract = µX,t / ωX. This expression was then rearranged to solve for t, yielding tfract – the time to achieve a given recovery fraction:  

[bookmark: _Hlk198013045]We simulated tfract for recovery fractions ranging from αX / ωX up to 0.99, as the function is undefined for values below αX / ωX or equal to or exceeding 1. This produced a continuous curve describing the time to recovery across the full range of valid fractions. Recovery times are thus based on the modeled asymptotic value of AGC recovery, rather than directly on field-based OGF reference measurements. In the following, only the time to 90% recovery (t90) is discussed. 
Forest AGC recovery trajectories were simulated for t going from 1 to 100 years using equation (1), which allows for a truthful visualization of the full sigmoidal curve. This range is typically sufficient to capture the complete shape of the recovery trajectory, including the inflection point and asymptotic phase. 
Early aboveground carbon accrual during the first 20 years of succession (CA20) was calculated as the difference between modeled total AGC at 20 years (AGC20) and the site-specific starting value (αX). Model fitting was initially performed on the full dataset, including remnant trees. However, exploratory analyses for sites in Liberia, the Republic of Guinea, and Sierra Leone yielded unrealistically high estimates of CA20 (exceeding 100 Mg C ha-1 by up to 50-60%), which were driven by near-zero estimates of the initial AGC value αX. This artefact arose because large remnant trees were largely absent from the youngest plots (approximately 5 years since disturbance) but became increasingly prevalent in older plots. As a result, their delayed appearance inflated apparent early-stage AGC accumulation rates. Because remnant tree abundance would not be expected to systematically increase with stand age under comparable land-use histories—and given the lack of detailed, plot-level land-use information—we interpret this pattern as a bias in the estimated starting conditions of succession rather than a true ecological signal.
To address this issue, remnant trees were identified and excluded based on a maximum diameter growth threshold of 5 cm yr-1. At the same time, fast-growing pioneer species (notably Musanga and Macaranga spp.) were retained, as these taxa can legitimately achieve such growth rates during early regeneration. This filtering procedure was applied consistently across all sites and plots to ensure comparability and avoid introducing additional biases in model parameter estimation. For the affected sites, CA20 estimates and corresponding environmental effect-size analyses were therefore derived from the remnant-removed dataset. In contrast, all other trajectory metrics and visualizations were based on the full dataset. Consequently, CA20 incorporates remnant tree contributions at all sites except those explicitly identified above, providing a more robust and ecologically meaningful estimate of early successional AGC accumulation where necessary, while preserving the full signal elsewhere.
Posterior distribution analysis
Model convergence was evaluated by making sure the R-hat statistics for the modeled parameters were always smaller than 1.01, as noted in Stan’s user manual2. Additionally, Stan outputs warning messages in case of divergent transitions or low effective sample sizes, and the Markov chains were visually checked using the ShinyStan package (version 2.6.0)7. Posterior predictive distribution checks were used to visually compare newly simulated observations with the actual data points.
The full Stan code used to model the AGC recovery trajectories can be found below.


data {	Stan code
  int<lower=0, upper=1> prior_only;
  int<lower=0> n_obs_rec;
  int<lower=0> n_obs_old;
  int<lower=0> n_reg;
  vector[n_obs_rec] A_rec;
  vector[n_obs_old] A_old;
  vector[n_obs_rec] t_obs;
  int<lower=1, upper=n_reg> reg_rec[n_obs_rec];
  int<lower=1, upper=n_reg> reg_old[n_obs_old];
  vector[n_reg] prior_logmu_ogf;
  real<lower=0> logdisp_OGF;
  real<lower=0> disp_age_help;
}
parameters {
  vector<lower=1e-6>[n_reg] sigma_rec_reg;
  vector<lower=1e-6>[n_reg] sigma_old_reg;
  vector<lower=1e-6>[n_reg] omega_reg;
  vector[n_reg] alpha_reg_tilde;
  vector[n_reg] lambda_reg_tilde;
  vector[n_reg] delta_reg_tilde;
  real<lower=1e-6, upper=500> mu_alpha;
  real<lower=1e-6, upper=1>   mu_lambda;
  real<lower=1e-6, upper=10>  mu_delta;
  real<lower=1e-6> sigma_alpha;
  real<lower=1e-6> sigma_lambda;
  real<lower=1e-6> sigma_delta;
  vector<lower=1e-6>[n_obs_rec] t_true;
}
transformed parameters {
  vector[n_reg] alpha_reg = mu_alpha * exp(alpha_reg_tilde * sigma_alpha);
  vector[n_reg] lambda_reg = mu_lambda * exp(lambda_reg_tilde * sigma_lambda);
  vector[n_reg] delta_reg  = mu_delta  * exp(delta_reg_tilde  * sigma_delta);
}

model {	Stan code
  // Age uncertainty: t_true ~ Normal(t_obs, disp_age_help * t_obs)
  for (i in 1:n_obs_rec)
    target += normal_lpdf(t_true[i] | t_obs[i], disp_age_help * t_obs[i]);
  // Informative lognormal prior on omega_reg (region-specific asymptote)
  for (r in 1:n_reg)
    target += normal_lpdf(log(omega_reg[r]) | prior_logmu_ogf[r], logdisp_OGF);
  // Old-growth likelihood
  for (i in 1:n_obs_old) {
    int reg = reg_old[i];
    if (!prior_only)
      A_old[i] ~ lognormal(log(omega_reg[reg]), sigma_old_reg[reg]);
  }
  // Secondary forest likelihood
  for (i in 1:n_obs_rec) {
    int reg = reg_rec[i];
    real mu = alpha_reg[reg] + (omega_reg[reg] - alpha_reg[reg]) *
              pow(1 - exp(-lambda_reg[reg] * t_true[i]), delta_reg[reg]);
    if (!prior_only)
      A_rec[i] ~ lognormal(log(mu), sigma_rec_reg[reg]);
  }
  // Priors
  sigma_rec_reg ~ normal(0, 3);
  sigma_old_reg ~ normal(0, 3);
  alpha_reg_tilde ~ std_normal();
  lambda_reg_tilde ~ std_normal();
  delta_reg_tilde ~ std_normal();
  mu_alpha  ~ exponential(0.05);
  mu_lambda ~ exponential(1);
  mu_delta  ~ exponential(0.1);
  sigma_alpha  ~ normal(0, 3);
  sigma_lambda ~ normal(0, 3);
  sigma_delta  ~ normal(0, 3);
}

Environmental effects on CA20, t90, and AGC20
Initial predictor set
The environmental effects on the trajectory properties (t90, CA20, and AGC20), estimated using the first Stan model, were assessed using a second model. As a first step, an initial set of 8 potential predictors was selected, based on prior beliefs that climatic, edaphic, and landscape conditions may govern recovery rates8–13. The included climatic variables were: mean annual temperature (MAT), temperature seasonality (TS; i.e., the standard deviation of mean monthly temperatures), mean annual precipitation (MAP), and the absolute value of the maximum cumulative water deficit (MCWD; calculated as the minimum value of the cumulative monthly water balance [precipitation minus potential evapotranspiration] reached during a year). All indices were extracted or computed from the historical WorldClim bioclimatic variables database (averaged over 1970 – 2000) at 30’’ resolution14. The landscape context was characterized using the 30-m resolution global tree cover map for the year 200015, corrected for oil palm plantations16. We derived the following three metrics: mean forest cover (MFC), contagion (CONT), and minimal distance to a 30% forest-cover threshold (D30). Mean forest cover and contagion were calculated within a 500 m radius as a representative scale to capture local landscape structure relevant to seed dispersal and edge effects, while remaining comparable across sites13. Contagion quantifies the spatial aggregation of forest cover within a given buffer, with higher values indicating a more clumped and spatially continuous forest pattern and lower values reflecting a more fragmented landscape. It was computed17 from the tree cover raster by first classifying pixel values into 10 discrete classes of 10% tree cover increments (0–10%, 10–20%, …, 90–100%), then counting how often neighboring pixels (using 8-neighbor connectivity) share the same class, and finally summarizing this spatial adjacency pattern using a Shannon entropy–based index normalized to its theoretical maximum, expressing contagion as a percentage. Lastly, the distance metric quantified the shortest distance from each plot to the nearest pixel with at least 30% tree cover. This threshold was selected because it is also applicable in particularly sparse forest landscapes such as miombo woodlands. Finally, while high-resolution data from local soil analyses are sparse, the potential influence of edaphic conditions on secondary forest recovery should not be neglected18–21. Therefore, we included soil pH-H2O of the upper 0–20 cm soil layer as a ‘master soil variable,’22 extracted from 30 m spatial resolution maps23. 
Predictor selection
To reduce the risk of overfitting and construct parsimonious models with reduced predictor redundancy and multicollinearity, we reduced the predictor set using projection predictive variable selection24–26, as implemented in the cv_varsel function of the projpred package (version 2.10.0)27. This approach searches for the minimal subset of predictors, starting from a full reference model, that achieves predictive performance close to that of the full model. Rather than searching for a single “true” model, projection predictive selection projects the predictive information contained in the full reference model onto progressively smaller submodels, adding predictors sequentially and identifying at each step the submodel that best preserves the predictive utility of the reference model. Because submodel selection is anchored to the regularized predictions of the full model rather than repeatedly refitting models directly to the observed outcomes, the approach is generally less prone to overfitting than classical stepwise selection procedures. 
This method is specifically intended for predictor reduction in predictive modeling settings and is not designed as a general-purpose feature selection procedure. We believe, however, that this method is adequate for the present analysis as our dataset (n = 32) leaves little room for redundant or correlated predictors without compromising model stability. 
To facilitate integration of t90, CA20, and AGC20 – derived from the preceding Stan model – into the projection predictive framework, an intermediate Bayesian linear regression model was fitted using the brms package (version 2.23.0)28. The response variable was specified as the per-site mean of the log-transformed posterior samples, with its associated uncertainty partially propagated into the model via the corresponding per-site standard deviation. To encourage sparsity and regularize the environmental effect size estimates, regularized horseshoe priors were placed on the regression coefficients, with the sparsity parameter (par_ratio) set to reflect a prior expectation of four relevant predictors out of eight candidates. Normal and exponential priors were specified for the intercept and standard deviation, respectively. The model implementation is shown below:
formula <- bf(y | mi(y_sd) ~ . ) 	R code
prior_rhs <- c(
	prior(horseshoe(df = 3, df_global = 3, df_slab = 4, scale_slab = 3, par_ratio = 4/(8-4)), class = "b"),
	prior(normal(0, 1), class = "Intercept"), 
	prior(exponential(1), class = "sigma"))
fit <- brm(  
formula   = formula,  
data      = data,
family    = gaussian(),
prior     = prior_rhs,
chains    = 4, iter = 10000, warmup    = 5000, cores     = 1,
save_pars = save_pars(all = TRUE),
control   = list(adapt_delta = 0.999, max_treedepth = 18))
Predictors were retained if they were present in 100% of 10 cross-validation folds (Supplementary Information Fig. S1) – a confirmation that the chosen subset is robust and not an artifact of any particular data partition. 
Final regression model with full uncertainty propagation
After the first predictor selection step using brms, the linear regression models were run again, but now with full uncertainty propagation from the response variables (t90, CA20, and AGC20) and only the response-specific retained predictors. 500 random draws from the metric’s posterior distribution were used as uncertain observations of a ‘true’ latent variable with a lognormal distribution:

with µdraw the vector containing 100 randomly drawn values from the posteriors of CA20, t90, or AGC20, µtrue the estimated true value of these metrics, and σ²draws the dispersion of the lognormal distribution. The resulting estimated true value was assumed to follow a lognormal distribution, with its median characterized by a multiple linear regression capturing the influence of environmental conditions: 

with µtrue [Mg C ha-1 or years] the estimated true value of CA20, t90, or AGC20, β0 the intercept of the multiple linear regression, β the vector of effect sizes, X the matrix of site-specific environmental covariate values, and σ²true the dispersion of the lognormal distribution. The dispersion parameters for both lognormal distributions, i.e., for the latent variable μtrue and the regression model, were evaluated on normal distributions with µ = 0 and σ = 5, as was the case for the effect sizes β. For the intercept  β0, the dispersion was set to σ = 10.
The full Stan code used to model the environmental effects can be found below.

Spatial predictions 
Using the posterior parameter estimates from the final Stan model, uncertainty was fully propagated into the spatial predictions. For each recovery metric, 1000 draws were randomly sampled from the joint posterior distribution of the intercept and regression coefficients. Each draw was then combined with the corresponding pre-scaled environmental covariate rasters – one raster layer per retained predictor – by computing the linear predictor pixel-wise, yielding a single spatially explicit prediction map per draw. This resulted in a stack of 1000 prediction maps per metric, each representing one plausible realization of the spatial pattern given posterior uncertainty in the regression parameters. Covariate rasters were standardized prior to prediction using the same centering and scaling parameters applied to the site-level environmental data during model fitting, ensuring that the spatial predictions are fully consistent with the regression model. Finally, pixel-wise summary statistics – mean, median, and 5th and 95th percentiles – were derived across the 1000-layer prediction stack, providing spatially explicit estimates of both central tendency and predictive uncertainty for each metric across the study region.
To delineate the spatial extent to which model predictions can be considered reliable, we assessed the Area of Applicability (AOA) for each response metric (t90, CA20, AGC20) using the CAST package in R (version 1.0.4)29. For each metric, predictor rasters were subset to the metric-specific variables identified during model selection and masked to the study region using a biome-based 30% canopy cover threshold mask15,16,30. The Dissimilarity Index (DI) and AOA were computed using the aoa function, with all predictors contributing equally to the dissimilarity calculation. The DI threshold was derived from distances among all training observations rather than cross-validation folds. The resulting binary AOA layer (1 = within, 0 = outside applicability) and continuous DI raster were exported for each metric.

data {	Stan code
  int<lower=1> N;
  int<lower=1> S;
  int<lower=1> P;
  matrix[N, P] X;
  matrix<lower=0>[N, S] metric_draws;
  int<lower=0> n_fixed;
  int<lower=1, upper=P> fixed_idx[n_fixed];
}
parameters {
  real intercept;
  vector[P] beta_raw;
  real<lower=0> sigma_proc;
  real<lower=0> sigma_meas;
  vector[N] log_metric_true;
}
transformed parameters {
  vector[P] beta = beta_raw;
  for (k in 1:n_fixed)
    beta[fixed_idx[k]] = 0;
}
model {
  intercept  ~ normal(0, 10);
  beta_raw   ~ normal(0, 5);
  sigma_proc ~ normal(0, 5);
  sigma_meas ~ normal(0, 5);

  log_metric_true ~ normal(intercept + X * beta, sigma_proc);
  for (i in 1:N)
    metric_draws[i] ~ lognormal(log_metric_true[i], sigma_meas);
}

Supplementary Information Figure S1 | Predictor ranking proportions across 10-fold cross-validation (CV) with fold-specific searches for a, the total aboveground carbon stocks at 20 years of succession (AGC20), b, the aboveground carbon accrual during the first 20 years of succession (CA20), and c, the time to 90% recovery (t90). Each tile shows the proportion of CV folds in which a given predictor was ranked at a certain position during the fold-wise forward search. Proportions are displayed as rounded whole percentages. Abbreviations: MCWD = maximum cumulative water deficit; MAT = mean annual temperature, ‘CONT’ = contagion; ‘D30’ = distance to nearest pixel with at least 30% tree cover, MAP = mean annual precipitation; ‘TS’ = temperature seasonality; ‘MFC’ = mean forest cover; ‘pH’ = soil pH-H2O in the upper 20 cm layer. The correlation matrix of response and predictor variables is shown in Supplementary Information Figure S5.

Supplementary Information Figure S2 | Spatial projection of the modeled uncertainty for the and total aboveground carbon stocks at 20 years of succession (AGC20; a), the aboveground carbon accrual during the first 20 years of succession (CA20; b), and the time to 90% recovery (t90; c). Uncertainty (Norm unc) is quantified as the credible interval width normalized by the median – specifically, the difference between the upper and lower 90% credible interval limits divided by the corresponding median value – based on 1,000 draws from the posterior distribution of the linear regression models. Scales are log-transformed to resolve spatial variation among the predominant low-value pixels. Pixels with a normalized uncertainty greater than 5 are shown in dark red. Regions where values were extrapolated beyond the range of the calibration data are indicated in Supplementary Information Fig. S4.

Supplementary Information Figure S3 | Area of Applicability (AOA) and Dissimilarity Index (DI) for  AGC20 (a), CA20 (b), and t90 (c) across African tropical forests. Left panels show the binary AOA, where dark green indicates locations within the applicability of the model (i.e., environmentally similar to the training data) and grey indicates locations outside it. Right panels show the continuous DI, reflecting the degree of dissimilarity between each pixel and the training data; values exceeding the threshold of 0.5 are shown in dark red. Predictions in areas outside the AOA should be interpreted with caution.

Supplementary Information Figure S4 | Environmental effects on the time to 50% recovery  (t50; a), as well as the parameter estimates of the sigmoidal recovery curve – b, lambda; c, alpha; and d, omega. For the 4th model parameter (delta), no relationships with the environmental predictor set were retained following predictor selection. Points indicate posterior median effect sizes, and error bars denote 90% credible intervals. Abbreviations: ‘MCWD’ = maximum cumulative water deficit; ‘MFC’ = mean percentage forest cover; ‘MAP’ = mean annual precipitation. ‘R²’ represents the Bayesian R-squared31. Effect size posterior distributions with 90% credible intervals that do not overlap zero are shown in green (positive) or red (negative).

Supplementary Information Figure S5 | Correlation matrix of response variables and the full initial predictor set. Abbreviations: response variables: ‘t90’ =  the time to 90% recovery; ‘CA20‘ = aboveground carbon accrual during the first 20 years of succession; ‘AGC20’ = total aboveground carbon stocks at 20 years of succession. Response variables: Abbreviations: MAP = mean annual precipitation; MCWD = maximum cumulative water deficit; MAT = mean annual temperature, ‘TS’ = temperature seasonality; ‘pH’ = soil pH-H2O in the upper 20 cm soil layer; ‘MFC’ = mean forest cover; CONT = contagion; ‘D30’ = distance to nearest pixel with at least 30% tree cover. Significance levels are indicated as follows: *** p < 0.001, ** p < 0.01, * p < 0.05, based on the cor.test function of  the stats package (version  4.5.0)32.
Supplementary tables
Supplementary Information Table S1 | Simulated parameter values of the sigmoidal regrowth curve for each of the 32 sites. Abbreviations: 'MLE' = maximum likelihood estimate in the joint posterior space; '5% Qt' and '95% Qt' = lower and upper bounds of the 90% credible interval, respectively. See the Supplementary Materials and Methods section for model details. Note that the MLE and median of the regional posterior distributions frequently diverge, as the joint posterior maximum does not necessarily coincide with the mode of any individual parameter's marginal distribution. The MLE is the appropriate choice when reconstructing or reporting the best-fit recovery trajectory, whereas the parameter- and region-specific medians are preferable when interpreting parameter values in isolation.

Country Site MLE Median 5% Qt 95% Qt MLE Median 5% Qt 95% Qt MLE Median 5% Qt 95% Qt MLE Median 5% Qt 95% Qt

Angola ANG_CCB 0.07 1.67 0.07 10.18 62.77 58.40 51.66 67.29 0.097 0.087 0.053 0.118 2.81 2.43 1.50 3.35

Cameroon CAM_MDNP 44.01 43.99 3.27 79.81 124.91 122.45 105.40 140.93 0.018 0.034 0.015 0.078 2.94 2.59 1.58 4.36

Côte d'Ivoire CI_Agbo1 0.65 0.55 0.20 1.01 155.21 164.26 131.47 194.25 0.044 0.038 0.029 0.049 2.84 2.69 2.22 3.32

Côte d'Ivoire CI_Badenou 0.14 0.06 0.00 0.56 65.81 38.58 30.64 49.84 0.045 0.067 0.041 0.109 2.63 2.47 1.82 3.30

Côte d'Ivoire CI_Bs-S 34.89 15.61 0.24 42.66 158.46 145.20 118.81 180.79 0.057 0.066 0.037 0.110 2.70 2.34 1.34 3.23

Côte d'Ivoire CI_Foumbou 0.16 0.69 0.04 3.00 69.26 79.80 56.84 99.45 0.051 0.040 0.027 0.059 2.86 2.65 2.02 3.66

Côte d'Ivoire CI_Ht-S 0.11 0.52 0.03 3.53 52.65 76.19 39.11 134.36 0.105 0.048 0.025 0.097 2.80 2.26 1.56 3.09

Côte d'Ivoire CI_Irobo 3.86 3.03 1.44 4.82 108.53 113.38 107.15 121.05 0.045 0.042 0.030 0.061 2.96 2.78 2.06 4.59

Côte d'Ivoire CI_Niegre 9.48 8.39 0.72 14.99 80.77 69.33 36.63 117.59 0.054 0.040 0.022 0.073 2.75 2.51 1.57 3.83

Côte d'Ivoire CI_Tene 0.77 0.68 0.10 2.32 157.91 99.86 62.71 157.73 0.036 0.043 0.026 0.068 2.84 2.61 1.93 3.75

Côte d'Ivoire CI_Yaya 0.51 0.48 0.13 1.27 239.44 240.28 125.87 511.18 0.039 0.039 0.023 0.063 2.89 2.67 2.01 3.64

DRC DRC_Babagulu 34.73 37.97 5.21 54.41 218.30 171.22 99.90 300.87 0.054 0.044 0.023 0.084 2.73 2.49 1.45 3.76

DRC DRC_NE-Kisangani 74.96 57.47 39.06 73.64 152.29 163.46 126.00 230.36 0.050 0.039 0.022 0.065 3.04 2.61 1.73 3.91

DRC DRC_Mabali 0.66 1.72 0.05 14.26 135.14 155.47 136.34 174.49 0.059 0.044 0.032 0.061 2.98 2.60 1.86 3.73

DRC DRC_Sakania 3.99 2.52 1.32 4.44 55.76 69.57 54.86 90.84 0.055 0.054 0.035 0.081 2.95 2.59 1.88 3.83

DRC DRC_Salonga 47.85 58.94 37.15 81.89 128.41 145.10 130.76 161.34 0.076 0.042 0.025 0.074 2.72 2.54 1.72 3.83

DRC DRC_Yoko 27.34 29.87 10.11 42.33 113.52 221.01 120.76 277.56 0.089 0.033 0.019 0.065 2.67 2.56 1.62 3.73

Gabon GAB_Lopé 17.14 13.21 0.22 29.21 178.32 179.32 163.32 201.44 0.082 0.070 0.045 0.102 2.75 2.14 1.27 3.13

Ghana GH_Abofour 43.63 34.49 19.98 48.36 71.91 70.10 44.20 123.93 0.070 0.050 0.026 0.099 2.82 2.49 1.52 3.56

Ghana GH_Bonsa 26.05 19.67 2.35 37.15 115.03 137.78 74.15 252.11 0.034 0.036 0.019 0.071 2.89 2.58 1.58 4.04

Republic of Guinea GU_Soyah 10.91 12.04 2.22 18.53 63.09 62.69 30.67 134.68 0.067 0.049 0.026 0.094 2.76 2.49 1.52 3.71

Republic of Guinea GU_Ziama 10.25 3.52 0.10 17.82 302.36 222.12 108.92 471.98 0.057 0.055 0.033 0.097 2.71 2.33 1.54 3.18

Liberia LIB_Gola 9.76 6.62 0.12 27.82 184.13 291.69 141.53 636.18 0.069 0.054 0.030 0.091 2.99 2.47 1.59 3.52

Liberia LIB_Sapo 2.96 0.96 0.04 6.59 513.45 439.89 220.40 836.42 0.072 0.060 0.037 0.097 3.01 2.67 2.02 3.90

Liberia LIB_Wonegizi 0.16 0.81 0.04 4.44 417.46 321.82 166.79 675.87 0.055 0.053 0.033 0.083 3.02 2.70 2.11 3.67

Mozambique MOZ_GiléNatPark 1.46 2.16 0.12 5.40 25.95 31.34 23.10 43.94 0.111 0.068 0.043 0.111 2.81 2.38 1.51 3.29

Mozambique MOZ_Machamba 1.28 0.50 0.05 1.35 25.03 24.05 18.63 32.87 0.085 0.070 0.045 0.105 3.14 2.45 1.73 3.39

Mozambique MOZ_Sussundenga 2.86 3.53 2.16 4.99 20.96 29.83 23.35 43.55 0.104 0.064 0.042 0.093 2.89 2.58 1.87 3.75

Sierra Leone SL_Gola 4.94 1.59 0.05 7.68 220.46 215.42 102.92 449.81 0.058 0.056 0.033 0.091 2.84 2.51 1.81 3.41

Sierra Leone SL_Outamba 9.67 5.13 0.15 17.10 98.54 80.31 35.73 172.54 0.046 0.058 0.031 0.110 2.66 2.42 1.48 3.38

Tanzania TAN_Kilwa 2.16 3.13 1.96 4.79 37.60 40.10 35.74 44.96 0.108 0.075 0.046 0.115 2.85 2.32 1.35 3.24

Zambia ZAM_Chintumukulu 0.00 0.58 0.03 3.72 34.07 26.48 22.06 36.52 0.081 0.067 0.041 0.107 2.87 2.46 1.68 3.52

Alpha (α) Omega (ω) Lambda (λ) Delta (δ)

